HL7® Iniciativa Costa Rica

Guía de Implementación de Homologación Regional (PH4H) de Costa Rica
0.1.0 - ci-build Costa Rica bandera

Guía de Implementación de Homologación Regional (PH4H) de Costa Rica - Versión en desarrollo (v0.1.0): no se debe usar en producción. Es un borrador en discusión en las mesas de trabajo de la Iniciativa HL7® Costa Rica y cambia sin aviso. Vea el ciclo de vida de las guías.

StructureMap: CRPractitionerToIPS

URL oficial: https://hl7.or.cr/fhir/ph4h/StructureMap/CRPractitionerToIPS Versión: 0.1.0
Standards status: Draft Nivel de madurez: 0 Nombre computable: CRPractitionerToIPS

Idioma: es

map "https://hl7.or.cr/fhir/ph4h/StructureMap/CRPractitionerToIPS" = "CRPractitionerToIPS"

uses "http://hl7.org/fhir/5.0/StructureDefinition/Practitioner" alias Practitioner as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/Practitioner" alias PractitionerR4 as target

imports "https://hl7.or.cr/fhir/ph4h/StructureMap/CRComun"

group CRPractitionerToIPS(source origen : Practitioner, target destino : PractitionerR4) {
  origen.id as idRecurso -> destino.id = idRecurso;
  origen -> destino.meta as metadatos then {
    origen -> metadatos.profile = 'http://hl7.org/fhir/uv/ips/StructureDefinition/Practitioner-uv-ips' "perfil";
  } "meta";
  origen.identifier as identificador where (use = 'official') -> destino.identifier as identificadorDestino then {
    identificador then Identificador(identificador, identificadorDestino) "datos";
    identificador where (system.startsWith('https://hl7.or.cr/fhir/sid/colegiado/')) -> identificadorDestino.assigner as colegio then Colegio(identificador, colegio) "colegio";
  } "identificador";
  origen.active as activo -> destino.active = activo "activo";
  origen.name as nombre -> destino.name as nombreDestino then Nombre(nombre, nombreDestino) "nombre";
  origen.telecom as telecom -> destino.telecom as telecomDestino then Telecom(telecom, telecomDestino);
  origen.address as direccion -> destino.address as direccionDestino then Direccion(direccion, direccionDestino) "direccion";
  origen.gender as sexo -> destino.gender = sexo "sexo";
  origen.birthDate as fechaNacimiento -> destino.birthDate = fechaNacimiento "nacimiento";
  origen.qualification as calificacion -> destino.qualification as calificacionDestino then {
    calificacion.identifier as numero -> calificacionDestino.identifier as numeroDestino then Identificador(numero, numeroDestino) "numero";
    calificacion.code as codigo -> calificacionDestino.code as codigoDestino then Concepto(codigo, codigoDestino) "codigo";
    calificacion.period as vigencia -> calificacionDestino.period as vigenciaDestino then Periodo(vigencia, vigenciaDestino) "vigencia";
    calificacion.issuer as emisor -> calificacionDestino.issuer as emisorDestino then Referencia(emisor, emisorDestino) "emisor";
  } "colegiaturaEspecialidad";
  origen.communication as comunicacion then {
    comunicacion.language as idioma -> destino.communication as idiomaDestino then Concepto(idioma, idiomaDestino) "codigo";
  } "idioma";
}

// Nombre del colegio según el sufijo del system del código de colegiado (cr-colegio-profesional).
group Colegio(source codigoColegiado : Identifier, target colegio : Reference) {
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/cmc') -> colegio.display = 'Colegio de Médicos y Cirujanos de Costa Rica' "cmc";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/ccd') -> colegio.display = 'Colegio de Cirujanos Dentistas de Costa Rica' "ccd";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/cfc') -> colegio.display = 'Colegio de Farmacéuticos de Costa Rica' "cfc";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/cmqc') -> colegio.display = 'Colegio de Microbiólogos y Químicos Clínicos de Costa Rica' "cmqc";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/cecr') -> colegio.display = 'Colegio de Enfermeras de Costa Rica' "cecr";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/cpp') -> colegio.display = 'Colegio de Profesionales en Psicología de Costa Rica' "cpp";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/cpn') -> colegio.display = 'Colegio de Profesionales en Nutrición de Costa Rica' "cpn";
  codigoColegiado where (system = 'https://hl7.or.cr/fhir/sid/colegiado/ctcr') -> colegio.display = 'Colegio de Terapeutas de Costa Rica' "ctcr";
}