HL7® Iniciativa Costa Rica

Guía de Implementación de Homologación Regional (PH4H) de Costa Rica
0.1.0 - ci-build Costa Rica bandera

Guía de Implementación de Homologación Regional (PH4H) de Costa Rica - Versión en desarrollo (v0.1.0): no se debe usar en producción. Es un borrador en discusión en las mesas de trabajo de la Iniciativa HL7® Costa Rica y cambia sin aviso. Vea el ciclo de vida de las guías.

StructureMap: CROrganizationToLACOrganization

URL oficial: https://hl7.or.cr/fhir/ph4h/StructureMap/CROrganizationToLACOrganization Versión: 0.1.0
Standards status: Draft Nivel de madurez: 0 Nombre computable: CROrganizationToLACOrganization

Idioma: es

map "https://hl7.or.cr/fhir/ph4h/StructureMap/CROrganizationToLACOrganization" = "CROrganizationToLACOrganization"

uses "http://hl7.org/fhir/5.0/StructureDefinition/Organization" alias Organization as source
uses "http://hl7.org/fhir/4.0/StructureDefinition/Organization" alias OrganizationR4 as target

imports "https://hl7.or.cr/fhir/ph4h/StructureMap/CRComun"

group CROrganizationToLACOrganization(source origen : Organization, target destino : OrganizationR4) {
  origen.id as idRecurso -> destino.id = idRecurso;
  origen -> destino.meta as metadatos then {
    origen -> metadatos.profile = 'http://racsel.org/StructureDefinition/LACOrganization' "perfil";
  } "meta";
  origen.identifier as identificador where (use = 'official') -> destino.identifier as identificadorDestino then Identificador(identificador, identificadorDestino) "identificador";
  origen.active as activa -> destino.active = activa "activa";
  origen.type as tipo -> destino.type as tipoDestino then Concepto(tipo, tipoDestino) "tipo";
  origen.name as nombre -> destino.name = nombre "nombre";
  origen.alias as nombreAlternativo -> destino.alias = nombreAlternativo;
  origen.contact as contacto where (purpose.exists().not()) then {
    contacto.telecom as telecom -> destino.telecom as telecomDestino then Telecom(telecom, telecomDestino);
    contacto.address as direccion -> destino.address as direccionDestino then Direccion(direccion, direccionDestino) "direccion";
  } "contactoGeneral";
  origen.partOf as superior -> destino.partOf as superiorDestino then Referencia(superior, superiorDestino) "superior";
}